KST指标底背离选股公式，通过变动率ROC合成动量震荡指标

本文主要是介绍KST指标底背离选股公式，通过变动率ROC合成动量震荡指标，希望对大家解决编程问题提供一定的参考价值，需要的开发者们随着小编来一起学习吧！

KST指标（KnowSureThing）是由马丁·普林斯（Martin Pring）于1992年发明的技术分析指标，目的在于及时识别价格趋势的变化和转折点，同时避免短期震荡指标不稳定的缺点。KST指标结合了四个周期的ROC（变动率指标）均线，根据一定的权重相加，合成为一个动量震荡指标。

KST指标的取值范围不是固定的，不同的股票、不同的行情，KST的值区别可能很大。KST指标和其他震荡指标的使用方法类似，可以通过金叉死叉、顶背离底背离、超买超卖、上穿下穿零轴等发出信号。KST指标脱胎于ROC指标，用均线和权重进行了平滑处理，一些分析方法依然适用，指标的正负代表价格变化的方向，偏离零轴的幅度代表动量的强弱。

一、KST指标公式副图

KST指标包含两条线（KST和KST均线），计算公式如下：

MAROC1 = 10日ROC的10日均线

MAROC2 = 15日ROC的10日均线

MAROC3 = 20日ROC的10日均线

MAROC4 = 30日ROC的15日均线

KST = (MAROC1 x 1) + (MAROC2 x 2) + (MAROC3 x 3) + (MAROC4 x 4)

KST均线 = 9日KST均线

KST指标公式副图：

N1:=10;N2:=15;N3:=20;N4:=30;

M1:=10;M2:=10;M3:=10;M4:=15;

P:=9;

ROC1:=100*(C-REF(C,N1))/REF(C,N1);

ROC2:=100*(C-REF(C,N2))/REF(C,N2);

ROC3:=100*(C-REF(C,N3))/REF(C,N3);

ROC4:=100*(C-REF(C,N4))/REF(C,N4);

MAROC1:=MA(ROC1,M1);

MAROC2:=MA(ROC2,M2);

MAROC3:=MA(ROC3,M3);

MAROC4:=MA(ROC4,M4);

KST:MAROC1+2*MAROC2+3*MAROC3+4*MAROC4;

KSTMA:MA(KST,P);

二、KST底背离主图指标公式

思路：KST指标底背离，就是价格创新低，但是KST指标不创新低。上文提到偏离零轴的幅度代表动量的强弱，价格创了新低，但是KST不创新低，就代表下跌的动量减弱。KST底背离指标用KST与KST均线的金叉发出信号，相对来说能过滤一些下跌动量减弱之后又加强或者继续下跌的情况，但是也不可能完全避免，还是要结合其他方法综合分析。

N1:=10;N2:=15;N3:=20;N4:=30;

M1:=10;M2:=10;M3:=10;M4:=15;

P:=9;

ROC1:=100*(C-REF(C,N1))/REF(C,N1);

ROC2:=100*(C-REF(C,N2))/REF(C,N2);

ROC3:=100*(C-REF(C,N3))/REF(C,N3);

ROC4:=100*(C-REF(C,N4))/REF(C,N4);

MAROC1:=MA(ROC1,M1);

MAROC2:=MA(ROC2,M2);

MAROC3:=MA(ROC3,M3);

MAROC4:=MA(ROC4,M4);

KST:=MAROC1+2*MAROC2+3*MAROC3+4*MAROC4;

KSTMA:=MA(KST,P);

JC:=CROSS(KST,KSTMA);

SC:=CROSS(KSTMA,KST);

T1:=BARSLAST(SC);

T2:=SUMBARS(SC,2);

LL1:=LLV(L,T1+1);

LL2:=LLV(L,T2);

KST1:=LLV(KST,T1+1);

KST2:=LLV(KST,T2);

XG:=LL1=LL2 AND KST1>KST2 AND JC;

STICKLINE(XG,H,L,0,1),COLORYELLOW;

STICKLINE(XG,C,O,3,0),COLOR117777;

STICKLINE(XG,C,O,2.5,0),COLOR119999;

STICKLINE(XG,C,O,2,0),COLOR11BBBB;

STICKLINE(XG,C,O,1.5,0),COLOR11DDDD;

STICKLINE(XG,C,O,1,0),COLOR44FFFF;

DRAWICON(XG,L,11);

三、KST底背离选股公式

N1:=10;N2:=15;N3:=20;N4:=30;

M1:=10;M2:=10;M3:=10;M4:=15;

P:=9;

ROC1:=100*(C-REF(C,N1))/REF(C,N1);

ROC2:=100*(C-REF(C,N2))/REF(C,N2);

ROC3:=100*(C-REF(C,N3))/REF(C,N3);

ROC4:=100*(C-REF(C,N4))/REF(C,N4);

MAROC1:=MA(ROC1,M1);

MAROC2:=MA(ROC2,M2);

MAROC3:=MA(ROC3,M3);

MAROC4:=MA(ROC4,M4);

KST:=MAROC1+2*MAROC2+3*MAROC3+4*MAROC4;

KSTMA:=MA(KST,P);

JC:=CROSS(KST,KSTMA);

SC:=CROSS(KSTMA,KST);

T1:=BARSLAST(SC);

T2:=SUMBARS(SC,2);

LL1:=LLV(L,T1+1);

LL2:=LLV(L,T2);

KST1:=LLV(KST,T1+1);

KST2:=LLV(KST,T2);

XG:LL1=LL2 AND KST1>KST2 AND JC;