[UnityShader入门精要读书笔记]09.在UnityShader中实现漫反射光照（逐顶点光照）

本文主要是介绍[UnityShader入门精要读书笔记]09.在UnityShader中实现漫反射光照（逐顶点光照），希望对大家解决编程问题提供一定的参考价值，需要的开发者们随着小编来一起学习吧！

为了防止点积结果为负值，我们需要使用max操作，而CG提供了这样的函数。使用另外一个CG函数也可以达到这样的目的。即saturate函数。

函数：saturate(x)

参数：x：用于操作的标量或矢量，可以是float，float2，float3等类型。

描述：把x截取在[0,1]范围内，如果x是一个矢量，那么会对它的每一个分量进行这样的操作。

1.逐顶点光照

shader "custom/Diffuse Vertex"{

        //1.为了得到并且控制材质的漫反射颜色，我们首先在shader的Properties语义块中声明了一个Color类型的属性，并把它的初始值设为白色。 

         Properties{

                  _Diffuse ("Diffuse",color) = (1,1,1,1)

         }

        //2.在subshader语义块中定义了一个Pass语义块。这是因为顶点/片元着色器的代码需要写在Pass语义块，而非SubShader语义块中。而且，我们在Pass的第一行指明了该Pass的光照模式：

       SubShader{

                Pass{

                       Tags{ "LightMode"="ForwardBase" }

                        //3.然后，使用CGPROGRAM和ENDCG来包围CG代码片，以定义最重要的顶点着色器和片元着色器代码。首先，我们使用#pragma指令来告诉Unity我们的顶点着色器和片元着色器叫什么。

                       CGPROGRAM

                       #pragma vertex vert

                       #pragma fragment frag

                      //4.为了使用Unity内置的一些变量，还要包含Unity的内置文件Lighting.cginc

                      #include "Lighting.cginc"

                      //5.定义一个和Properties声明的属性类型相匹配的变量。

                     fixed4 _Diffuse; 

                     //6.定义顶点着色器的输入和输出结构体（输出结构体同时也是片元着色器的输入结构体）

                     struct a2v{

                            float4 vertex : POSITION;

                            float3 normal : NORMAL;

                     };

                     struct v2f{

                           float4 pos : SV_POSITION;

                           fixed3 color : COLOR;

                     };

                     v2f vert(a2v v){

                               v2f o;

                               o.pos = mul(UNITY_MATRIX_MVP, v.vertex);

                               fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;

                               fixed3 worldNormal = normalize(mul(v.normal, (float3x3)_World2Object));

                               fixed3 worldLight = normalize(_WorldSpaceLightPos0.xyz);

                               fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal,worldLight));

                               o.color = ambient + diffuse;

                               return o;

                     }

                     fixed4 frag(v2f i) : SV_Target{

                            return fixed4(i.color,1.0);

                     }

                    ENDCG

               }

       }

       Fallback "Diffuse"

}

顶点着色器最基本的任务就是把顶点位置从模型空间转换到裁剪空间中，因此我们需要使用Unity内置的模型*世界*投影矩阵UNITY_MARTIX_MVP来完成这样的坐标变换。接下来我们使用了UNITY_LIGHTMODEL_AMBIENT得到了环境光部分。

然后，就是真正计算漫反射光照的部分。计算漫反射光照我们需要4个参数，我们知道了漫反射颜色_Diffuse已经顶点法线v.normal。我们还需要知道光源的颜色和轻度信息以及光源方向，Unity给我们提供了一个内置变量_LightColor0来访问该Pass处理的光源的颜色和强度信息，而光源方向可以通过_WorldSpaceLightPos0来得到。此方法仅适用于单光源。

在计算法线和光源方向之间的点积时，我们需要选择他们所在的坐标系，只有两者处于同一坐标空间下，它们的点积才有意义。在这里，我们选择了世界坐标空间。而由a2v得到的顶点法线是位于模型空间下的，因此我们首先需要把顶点法线转换到世界空间中。此前，我们已经知道可以使用顶点变换矩阵的逆转置矩阵对法线进行相同的变换，因此我们首先得到模型空间到世界空间的变换矩阵的逆矩阵_World2Object,然后通过调换它在mul函数中的位置，得到和转置矩阵相同的矩阵乘法。由于法线是一个三维矢量，因此我们只需要截取_World2Object的前三行前三列即可。

在得到了世界空间中的法线和光源方向后，我们需要对它们进行归一化操作。在得到了它们的点积的结果后，我们需要防止这个结果为负值。为此，我们使用了saturate函数。saturate函数是CG提供的一种函数，它的作用是可以把参数截取到[0,1]的范围内。最后，再与光源的颜色和强度以及材质的漫反射颜色相乘即可得到最终的漫反射光照部分。     

对于细分程度较高的模型，逐顶点光照已经可以得到比较好的光照效果了，但对于一些细分程序较低的模型，逐顶点光照就会出现一些问题。会在背光面和向光面交界处有一些锯齿。                                                                                                                                                                                  

这篇关于[UnityShader入门精要读书笔记]09.在UnityShader中实现漫反射光照（逐顶点光照）的文章就介绍到这儿，希望我们推荐的文章对编程师们有所帮助！

---