即时战略游戏开发—Rectangle对象应用实战+Array对象中被你忽略的方法

本文主要是介绍即时战略游戏开发—Rectangle对象应用实战+Array对象中被你忽略的方法,希望对大家解决编程问题提供一定的参考价值,需要的开发者们随着小编来一起学习吧!

上一次发了一篇Rectangle对象在游戏开发中的应用的文章,下面还是围绕Rectangle对象介绍一下在即时战略游戏中的实际应用。同时还将会用到数组对象中平时用的不多的几个方法。

      玩过《红警》或者《帝国时代》的朋友应该都知道,这类游戏有一个框选功能。鼠标在屏幕上拉一个框,处在方框之内的都被选中。如图:


 

 

 

 

 

 

      我们这个例子的原型是这样的:

      1、坦克的选择有框选和点击选择两种方式。
      2、坦克被选中后会显示自己被选中
      3、鼠标在屏幕上点击时,如果有坦克被选中,坦克将移动到鼠标点击位置附近(是附近不是鼠标点击位置),同时选择状态自动取消。
      4、如果有新的选择,则之前选择的坦克的选择状态将取消。

      先看一下做好的效果,点击这里

讲解:

      1、坦克的被选择和非选择状态的实现
      在我们的坦克类里面设置一个属性select,通过set方法来实现。当select=true时,让坦克的帧跳转到第2帧。当select=false时,让坦克的帧跳转到第1帧。

      在坦克类Tank中设定一个私有变量_select,然后设置getter/setter

      public function get select():Boolean
      {
           return _select;
      }
      public function set select(s:Boolean)
      {
           _select=s;
           this.gotoAndStop(_select==true? 2:1)
      }

      2、坦克点击选择的实现
      我们没有必要给每一辆坦克都注册鼠标事件,只要给放置坦克的容器注册一个鼠标事件就能知道用户点击的是哪一辆坦克。
      MouseEvent有target和currentTarget两个属性。这两个属性有区别,target返回的是最先接收到点击的交互物体,而currentTarget返回的是你addEventListener注册的这个对象。见下图:
     

 

 

      3、坦克框选的实现
      基本上我们会需要做这几个步骤:
      A、通过鼠标的MOUSE_MOVE事件实现拉框效果。
      B、通过画的这个框和物体的边界框比较判断那些物体被选择了
      C、让这些物体变为选择的状态
      D、当鼠标再一次被点击时,如果有坦克在选择状态下并且点击的位置是空地,则所有坦克向目标点附近移动,同时取消所有选择状态。

      实现思路是——准备两个数组一个记录所有坦克的引用tankList,一个记录任何时候被选择的坦克的引用selectList。

       这里我们会用到平时使用不多的两个数组里的方法forEach()和filter(),这两个方法将在这里发挥重要的作用。数组对象共有5个你可能没怎么关注的新的方法。如下图:\





 
 
 

      来看一下我们在这个例子里面是怎么用的:

      selectList=tankList.filter(selectTank); //找出被框选的坦克
      selectList.forEach(moveTank); //让所有被选中的坦克移动

      function selectTank(element:*, index:int, arr:Array)
      {
           //如果坦克边界与选框相交,则让坦克显示为选择状态
           if(element.getBounds(this).intersects(rec)==true)
           {
                element.select=true;
                return true;
          }
           return false;
      }

      function moveTank(element:*, index:int, arr:Array)
      {
         element.select=false; //移动时取消坦克的选择状态
          var randomX=targetPoint.x+Math.random()*150-75;
          var randomY=targetPoint.y+Math.random()*150-75;
          element.moveTo(randomX,randomY); //让坦克移动
       }

 

完整代码如下:
==================================================================================
主程序:
import Tank;

var map:Sprite=new Sprite(); //定义一个地图容器
var tankList:Array=new Array(); //定义一个记录所有坦克的列表
var selectList:Array=new Array(); //定义一个记录当前选择的坦克的列表
var targetPoint:Point; //目标点
var rec:Rectangle; //选择框的矩形对象
var shape:Shape=new Shape(); //用于显示选择框的Shape对象
var isMove:Boolean; //选择坦克还是移动坦克
addChild(map); //把地图放入显示列表
addChild(shape); //选择框

//产生20辆坦克
for (var i=0;i<20;i++)
{
    var tank=new Tank();
    map.addChild(tank);
    tankList.push(tank); //把坦克的引用记录下来
}

addEventListener(MouseEvent.MOUSE_DOWN,mouseDownHandler)
addEventListener(MouseEvent.MOUSE_UP,mouseUpHandler)

function mouseDownHandler(evt:MouseEvent)
{
    targetPoint=new Point(evt.currentTarget.mouseX,evt.currentTarget.mouseY);
    //如果点击在坦克上,则此坦克被选中。否则注册一个鼠标移动事件
    if((evt.target is Tank)==true)
    {
        selectList.forEach(unSelect); //将已选择链表中所有坦克变为非选择状态
        clearArray(selectList); //清空selectList数组
        evt.target.select=true
        selectList.push(evt.target)
       isMove=false; 
    }
    else
    {
        addEventListener(MouseEvent.MOUSE_MOVE,mouseMoveHandler)
       isMove=true;
   }
}
function mouseMoveHandler(evt:MouseEvent)
{
    var recWidth=evt.currentTarget.mouseX-targetPoint.x;
    var recHeight=evt.currentTarget.mouseY-targetPoint.y;
    shape.graphics.clear();
    shape.graphics.beginFill(0x99ccff,0.2);
    shape.graphics.lineStyle(2, 0x000000,0.8);            
    shape.graphics.drawRect(targetPoint.x,targetPoint.y, recWidth, recHeight)
    shape.graphics.endFill(); 
}
function mouseUpHandler(evt:MouseEvent)
{
    removeEventListener(MouseEvent.MOUSE_MOVE,mouseMoveHandler)
    rec=shape.getBounds(this);
    shape.graphics.clear();
    if(rec.width>0&&rec.height>0)//重新框选
   {
        selectList.forEach(unSelect);
       clearArray(selectList);
        selectList=tankList.filter(selectTank);
       rec.width=rec.height=0;
   }
    else if(selectList.length>0&&isMove==true)
    {
        selectList.forEach(moveTank)
        clearArray(selectList);
    }
}
//用来筛选哪些坦克被选中的过滤方法
function selectTank(element:*, index:int, arr:Array)
{
    if(element.getBounds(this).intersects(rec)==true)
   {
        element.select=true;
       return true;
    }
    return false;
}
//取消坦克的选择状态的方法
function unSelect(element:*, index:int, arr:Array)
{
      element.select=false;
}
//移动坦克的方法
function moveTank(element:*, index:int, arr:Array)
{
    element.select=false;
    var randomX=targetPoint.x+Math.random()*150-75;
    var randomY=targetPoint.y+Math.random()*150-75;
    element.moveTo(randomX,randomY);
}
function clearArray(arr:Array)
{
    while(arr.length>0)
   {
       arr.shift();
    }
}

==================================================================================
坦克类

package
{
/**
* 一个简单的坦克类的模型
* 作者:闪刀浪子
* blog:http://hi.baidu.com/mr_ziqiang
*/
import flash.display.MovieClip
import flash.geom.Point
import flash.events.Event;

public class Tank extends MovieClip
{
   private var speed:int; //坦克的速度
   private var targetPoint:Point; //目标点
   private var _select:Boolean; //此坦克是否被选中,选中则显示被选中状态
   /**
   * Tank类构造函数
   * 初始化的时候随机产生一个坐标
   */
   public function Tank()
   {
    this.mouseChildren=false; //这里记得禁用子对象的鼠标点击
    this.x=300*Math.random()+10; //设置坦克出现的时候在左上角100*100大小范围类随机
    this.y=300*Math.random()+10;
    this.scaleX=this.scaleY=1+Math.random(); //体积大的就是红警中最牛的猛犸坦克了
    speed=(3-scaleX)*4; //呵呵,体积越大速度当然要越慢了
   }
   public function moveTo(tx:Number,ty:Number)
   {
    this.removeEventListener(Event.ENTER_FRAME,onMove);
    targetPoint=new Point(tx,ty);
    this.addEventListener(Event.ENTER_FRAME,onMove);
   }
   private function onMove(evt:Event)
   {
    var dx = targetPoint.x - this.x;
    var dy = targetPoint.y - this.y;
    var radian = Math.atan2(dy, dx);//求新角度  
    body.rotation=radian*180/Math.PI; //我的坦克类里有一个body的mc,方便转向的时候绿框不随着转
    if (dx * dx + dy * dy <= speed * speed)
    {
     this.x=targetPoint.x;
     this.y=targetPoint.y;
     this.removeEventListener(Event.ENTER_FRAME,onMove);
    }
    else
    {
     var vx = Math.cos(radian) * speed;//求增量
     var vy = Math.sin(radian) * speed;
    
     this.x += vx;
     this.y += vy;
    }   
   }
   public function get select():Boolean
   {
    return _select;
   }
   public function set select(isSelect:Boolean)
   {
    _select=isSelect;
    if(_select==true)
    {
     this.gotoAndStop(2);
    }
    else
    {
     this.gotoAndStop(1);
    }
   }  
}
}

这篇关于即时战略游戏开发—Rectangle对象应用实战+Array对象中被你忽略的方法的文章就介绍到这儿,希望我们推荐的文章对编程师们有所帮助!



http://www.chinasem.cn/article/959853

相关文章

Linux换行符的使用方法详解

《Linux换行符的使用方法详解》本文介绍了Linux中常用的换行符LF及其在文件中的表示,展示了如何使用sed命令替换换行符,并列举了与换行符处理相关的Linux命令,通过代码讲解的非常详细,需要的... 目录简介检测文件中的换行符使用 cat -A 查看换行符使用 od -c 检查字符换行符格式转换将

SpringBoot实现数据库读写分离的3种方法小结

《SpringBoot实现数据库读写分离的3种方法小结》为了提高系统的读写性能和可用性,读写分离是一种经典的数据库架构模式,在SpringBoot应用中,有多种方式可以实现数据库读写分离,本文将介绍三... 目录一、数据库读写分离概述二、方案一:基于AbstractRoutingDataSource实现动态

Java中的String.valueOf()和toString()方法区别小结

《Java中的String.valueOf()和toString()方法区别小结》字符串操作是开发者日常编程任务中不可或缺的一部分,转换为字符串是一种常见需求,其中最常见的就是String.value... 目录String.valueOf()方法方法定义方法实现使用示例使用场景toString()方法方法

Java中List的contains()方法的使用小结

《Java中List的contains()方法的使用小结》List的contains()方法用于检查列表中是否包含指定的元素,借助equals()方法进行判断,下面就来介绍Java中List的c... 目录详细展开1. 方法签名2. 工作原理3. 使用示例4. 注意事项总结结论:List 的 contain

Spring Boot + MyBatis Plus 高效开发实战从入门到进阶优化(推荐)

《SpringBoot+MyBatisPlus高效开发实战从入门到进阶优化(推荐)》本文将详细介绍SpringBoot+MyBatisPlus的完整开发流程,并深入剖析分页查询、批量操作、动... 目录Spring Boot + MyBATis Plus 高效开发实战:从入门到进阶优化1. MyBatis

MyBatis 动态 SQL 优化之标签的实战与技巧(常见用法)

《MyBatis动态SQL优化之标签的实战与技巧(常见用法)》本文通过详细的示例和实际应用场景,介绍了如何有效利用这些标签来优化MyBatis配置,提升开发效率,确保SQL的高效执行和安全性,感... 目录动态SQL详解一、动态SQL的核心概念1.1 什么是动态SQL?1.2 动态SQL的优点1.3 动态S

Python基于wxPython和FFmpeg开发一个视频标签工具

《Python基于wxPython和FFmpeg开发一个视频标签工具》在当今数字媒体时代,视频内容的管理和标记变得越来越重要,无论是研究人员需要对实验视频进行时间点标记,还是个人用户希望对家庭视频进行... 目录引言1. 应用概述2. 技术栈分析2.1 核心库和模块2.2 wxpython作为GUI选择的优

Pandas使用SQLite3实战

《Pandas使用SQLite3实战》本文主要介绍了Pandas使用SQLite3实战,文中通过示例代码介绍的非常详细,对大家的学习或者工作具有一定的参考学习价值,需要的朋友们下面随着小编来一起学习学... 目录1 环境准备2 从 SQLite3VlfrWQzgt 读取数据到 DataFrame基础用法:读

macOS无效Launchpad图标轻松删除的4 种实用方法

《macOS无效Launchpad图标轻松删除的4种实用方法》mac中不在appstore上下载的应用经常在删除后它的图标还残留在launchpad中,并且长按图标也不会出现删除符号,下面解决这个问... 在 MACOS 上,Launchpad(也就是「启动台」)是一个便捷的 App 启动工具。但有时候,应

SpringBoot日志配置SLF4J和Logback的方法实现

《SpringBoot日志配置SLF4J和Logback的方法实现》日志记录是不可或缺的一部分,本文主要介绍了SpringBoot日志配置SLF4J和Logback的方法实现,文中通过示例代码介绍的非... 目录一、前言二、案例一:初识日志三、案例二:使用Lombok输出日志四、案例三:配置Logback一