通达信涨停回马枪选股公式，涨停回调不破起涨点

本文主要是介绍通达信涨停回马枪选股公式，涨停回调不破起涨点，希望对大家解决编程问题提供一定的参考价值，需要的开发者们随着小编来一起学习吧！

在编写涨停回马枪选股公式之前，我们需要先深入了解如何编写涨停公式。在前面的文章《创业板、科创板也适用的通达信涨停指标公式怎么写？》中介绍了涨停指标公式的编写方法，然而这种方法偶尔还是会有漏网之鱼。因此借此机会，我们将结合其他网友分享的经验，重新对涨停指标公式的编写方法进行梳理和介绍，以提供更为精准的信号。

首先需要了解两个函数，ZTPRICE和FINANCE。

1、ZTPRICE函数

含义：涨停价

用法：ZTPRICE(REF(C,1),0.1)，表示在昨天的收盘价基础上，按10%计算得到今天的涨停价。（涉及到复权有可能不准）

2、FINANCE函数

FINANCE函数在前一篇文章《关联财务函数FINANCE，编写基本面指标公式》中已经进行了介绍，本文只介绍FINANCE(3)。

FINANCE(3)表示沪深京品种类型，当它的值等于下面的数值，代表不同的品种。

0:指数，1:A股主板，2:北证A股，3:创业板，4:科创板，5:B股，6:债券，7:基金，8:权证，9:其它，10:非沪深京品种

举例：FINANCE(3)=3，就表示品种是创业板；FINANCE(3)=4就表示品种是创业板。

一、涨停主图指标公式

思路：用IF判断来区分创业板、科创板、主板，分布设置不同的涨停板幅度，当K线是涨停板时，K线颜色变为洋红色。

P1:=FINANCE(3)=3;{品种为创业板}

P2:=FINANCE(3)=4;{品种为科创板}

ZF:=IF(P1 OR P2,0.2,0.1);{当品种为创业板、科创板，结果为0.2；其他品种，结果为0.1}

ZTJ:=ZTPRICE(REF(C,1),ZF);{涨停价}

ZT:=C=ZTJ;{收盘价为涨停价}

STICKLINE(ZT,H,L,0,0),COLORMAGENTA;

STICKLINE(ZT,C,O,3,0),COLORMAGENTA;

DRAWSL(ZT,L,0,20,0),COLORMAGENTA;

FINANCE(3)函数有10个品种，公式中ZF变量只区分了20%和10%这两种涨停板情况，分别对应创业板科创板和主板，考虑到公式主要应用于沪深股票，所以并没用继续区分。如果想进一步区分，比如北交所30%，在原来IF判断的基础上，在外面再套一层IF进行判断。

二、涨停回马枪主图指标公式

思路：涨停之后缩量回调，收盘价不破涨停K线的低点。

MA5:MA(C,5);

MA10:MA(C,10);

MA20:MA(C,20);

MA60:MA(C,60);

P1:=FINANCE(3)=3;

P2:=FINANCE(3)=4;

ZF:=IF(P1 OR P2,0.2,0.1);

ZTJ:=ZTPRICE(REF(C,1),ZF);

ZT:=C=ZTJ;

STICKLINE(ZT,H,L,0,0),COLORMAGENTA;

STICKLINE(ZT,C,O,3,0),COLORMAGENTA;

DRAWSL(ZT,L,0,20,0),COLORMAGENTA;

N:=50;

H1:=HHV(H,N);

L1:=LLV(H,N);

A1:=(H1-L1)/L1*100<80;{限制最近涨幅}

A2:=COUNT(ZT,N)<=2;{限制涨停次数}

T:=BARSLAST(ZT);

LL:=REF(L,T);

HV:=HHV(V,T+1);

LV:=LLV(V,T+1);

A3:=LV<=HV/3;{缩量}

A4:=EXIST(ZT,15);

A5:=EVERY(C>LL,T);{回调收盘价不破涨停K线低点}

A6:=C>O AND V>REF(V,1)*1.2;{放量阳线}

A7:=T>1;

AA:=A1 AND A2 AND REF(A3,1) AND REF(A4,1) AND A5 AND A6 AND A7;

AA1:=AA AND COUNT(AA,T)=1;

XG:=FILTER(AA1,15);

STICKLINE(XG,H,L,0,1),COLORYELLOW;

STICKLINE(XG,C,O,3,0),COLOR117777;

STICKLINE(XG,C,O,2.5,0),COLOR119999;

STICKLINE(XG,C,O,2,0),COLOR11BBBB;

STICKLINE(XG,C,O,1.5,0),COLOR11DDDD;

STICKLINE(XG,C,O,1,0),COLOR44FFFF;

DRAWICON(XG,L,11);

三、涨停回马枪选股公式

P1:=FINANCE(3)=3;

P2:=FINANCE(3)=4;

ZF:=IF(P1 OR P2,0.2,0.1);

ZTJ:=ZTPRICE(REF(C,1),ZF);

ZT:=C=ZTJ;

N:=50;

H1:=HHV(H,N);

L1:=LLV(H,N);

A1:=(H1-L1)/L1*100<80;

A2:=COUNT(ZT,N)<=2;

T:=BARSLAST(ZT);

LL:=REF(L,T);

HV:=HHV(V,T+1);

LV:=LLV(V,T+1);

A3:=LV<=HV/3;

A4:=EXIST(ZT,15);

A5:=EVERY(C>LL,T);

A6:=C>O AND V>REF(V,1)*1.2;

A7:=T>1;

AA:=A1 AND A2 AND REF(A3,1) AND REF(A4,1) AND A5 AND A6 AND A7;

AA1:=AA AND COUNT(AA,T)=1;

XG:FILTER(AA1,15);