通达信自动包络线指标公式以及ATR通道指标

本文主要是介绍通达信自动包络线指标公式以及ATR通道指标，希望对大家解决编程问题提供一定的参考价值，需要的开发者们随着小编来一起学习吧！

根据亚历山大·埃尔德在其著作《以交易为生》中的描述，自动包络线的设计思路是将通道看作试穿衬衫一样，寻找那些穿起来既不过松也不过紧的衬衫，只让手腕和脖子露在外面。自动包络线能够适应最近的行情波动，只有在极端情况下，价格才会超出通道范围。

书中使用13日EMA均线和26日EMA均线，通道平行于26日EMA均线。

上通道=EMA26+通道系数*EMA26

下通道=EMA26-通道系数*EMA26

通道系数需要不断调整，直到通道线能够完整地包含最近100根K线的95%的价格数据。

通道系数的计算比较费脑，不过技术Pie还是想出了一个感觉不错的方法。假设通道已经存在，那最近100根K线，有95根已经被包住在通道之内，还有5根没有被包住，这5根K线是偏离EMA26日均线最远的（偏离程度前5名，如下图中12345）。如果我们找到偏离EMA26日均线第6远的K线，计算其偏离值，就可以确定通道系数。因为只要把第6远的这根K线包住，剩下的94根就都包含在通道内了。

一、自动包络线指标公式

EMA13:=EMA(CLOSE,13);

EMA26:=EMA(CLOSE,26);

PL:=MAX(H-EMA26,EMA26-L);{计算偏离EMA26均线的程度}

P6:=CONST(FINDHIGH(PL,0,99,6));{最近100根偏离第6远的K线的偏离程度}

N:=P6/EMA26;{计算通道系数}

UP:EMA26+N*EMA26,DOTLINE,COLORYELLOW;{上通道，黄色虚线}

DN:EMA26-N*EMA26,DOTLINE,COLORYELLOW;{下通道，黄色虚线}

{下面是动力系统指标公式}

DIF:=EMA(C,12)-EMA(C,26);

DEA:=EMA(DIF,9);

MACD:=(DIF-DEA)*2;

RBAR:=EMA13>REF(EMA13,1) AND MACD>REF(MACD,1);

CBAR:=EMA13<REF(EMA13,1) AND MACD<REF(MACD,1);

GBAR:=IF(RBAR OR CBAR,0,1);

STICKLINE(RBAR,H,L,0,1),COLORRED;

STICKLINE(RBAR,C,O,3,1),COLORRED;

STICKLINE(CBAR,H,L,0,0),COLORCYAN;

STICKLINE(CBAR,C,O,3,0),COLORCYAN;

STICKLINE(GBAR,H,L,0,0),COLORLIGRAY;

STICKLINE(GBAR,C,O,3,0),COLORLIGRAY;

EMA13,COLORWHITE;

EMA26,COLORYELLOW;

公式需要注意两点：

1、为了实现自动调整通道，P6:=CONST(FINDHIGH(PL,0,99,6));这一句用了CONST函数，这样会根据最新的行情修正通道，显示出的通道不适合历史行情。如果要查看历史情况，可以使用“训练模式”或者“沙盘推演”进行复盘。另外如果想直接查看历史情况，可以去掉CONST函数，P6:=FINDHIGH(PL,0,99,6);，这样历史行情的通道不会变化，单纯从图形上来说，就没有自动包络的效果了。

2、公式中的动力系统部分，在之前的文章中已经做了详细介绍，这里不再赘述。

二、ATR通道指标公式

亚历山大·埃尔德的朋友克里·洛沃恩使用ATR通道，三组通道线分别设置在距离21日EMA均线1倍、2倍、3倍ATR的位置。正常的波动往往在1倍ATR的通道内，极端行情才会冲出3倍ATR通道。

ATR是平均真实波幅，先计算真实波幅，取“当天最高价与最低价的波幅”、“昨天收盘价与今天最高价的波幅”、“昨天收盘价与今天最低价的波幅”这三者的最大值，然后再计算最大值的14日移动平均值，得到ATR。

MTR:=MAX(MAX((H-L),ABS(REF(C,1)-H)),ABS(REF(C,1)-L));

ATR:=MA(MTR,14);

EMA21:EMA(C,21),COLORWHITE;

UP1:EMA21+ATR,COLORYELLOW;{1倍ATR上通道}

UP2:EMA21+ATR*2,DOTLINE,COLORMAGENTA;{2倍ATR上通道}

UP3:EMA21+ATR*3,COLORLIGRAY;{3倍ATR上通道}

DN1:EMA21-ATR,COLORYELLOW;{1倍ATR下通道}

DN2:EMA21-ATR*2,DOTLINE,COLORMAGENTA;{2倍ATR下通道}

DN3:EMA21-ATR*3,COLORLIGRAY;{3倍ATR下通道};