PushButton引擎学习笔记1

(此文为转载，原出处不详，而由于某种原因只通过CSDN的BLOG在不同地点不同网域共享信息，如有不妥请告知，抱歉)

1，理解PBE类。

PBE类在PB引擎中就相当于我们程序中的Main一样，是一切PBE引起模块的起点。其下面的方法和属性都是静态的，一方面，PBE类作为引擎的启动入口，另一方面，该类对引擎的各个模块有很好的组织作用，通过其静态成员很好的管理着各个模块。如：inputManager对按键等进行着监听、levelManager对游戏关口进行着管理，还有soundManager、screenManager、templateManager等。

2，SceneView

在PB中，SceneView相当于Flash IDE主文档类的下一层。看源码，很容易知道这一点：

public function SceneView()
   {
    if(PBE.mainClass)
    {
     PBE.mainClass.addChild(this);
     width = PBE.mainStage.stage.stageWidth;
     height = PBE.mainStage.stage.stageHeight;
     name = "SceneView";
    }
   }

上面的mainClass就相当于Flash IDE中的主文档，而SceneView则是在其基础上新建的一层。SceneView也是PB中所有可见对象被加载到的最底一层。例如：你要在舞台上呈现一个圆形，大概的操作流程是：初始化一个SceneView，新new一个圆形对象，然后将圆形“关联”到这个SceneView中。

3，Entity

PB中，所有被加载到SceneView中的，都被看做是一个实体：Entity，与Entity相关的类和接口因为这个原因会被经常用到。

下面用一个简单的实例说明这些，在舞台上画出一个长方形：

package
{
 import com.pblabs.engine.entity.IEntity;
 import com.pblabs.engine.entity.*;
 import com.pblabs.rendering2D.SimpleShapeRenderer;
 import com.pblabs.rendering2D.SimpleSpatialComponent;
 import com.pblabs.rendering2D.ui.SceneView;
 import flash.display.Sprite;
 import flash.events.Event;
 import com.pblabs.engine.PBE;
 import flash.geom.Point;
 
 /**
  * ...
  * @author luoyuqiang
  */
 public class Main extends Sprite
 {
  public function Main():void
  {
   if (stage) init();
   else addEventListener(Event.ADDED_TO_STAGE, init);
  }
  
  private function init(e:Event = null):void
  {
   PBE.startup(this);
   createScene();//创建一个SceneView
   createHero();//创建一个Entity
   removeEventListener(Event.ADDED_TO_STAGE, init);
  }
  private function createHero():void
  {
   var hero:IEntity = PBE.allocateEntity();
   var spatial:SimpleSpatialComponent = new SimpleSpatialComponent();
   spatial.position = new Point(0, 0);
   spatial.size = new Point(102, 102);    
   spatial.spatialManager = PBE.spatialManager;//用到了PBE的spatialManager
   hero.addComponent(spatial, "spatial" );                            
   var retangle:SimpleShapeRenderer = new SimpleShapeRenderer();
   retangle.isSquare = true;
   retangle.fillColor = 0x000000;
   retangle.alpha = 1;
   retangle.lineSize = 1;
   retangle.size = new Point(200, 200);
   retangle.scene = PBE.scene;
   retangle.positionProperty = new PropertyReference("@spatial.position");
   retangle.rotationProperty = new PropertyReference("@spatial.rotation");
   hero.addComponent(retangle, "retangle");
   hero.initialize("Hero");
  }
  private function createScene():void
  {
   var scene:SceneView = new SceneView();
   PBE.initializeScene(scene);
  }
 }
}

另外，要说明的是，你只用PB的一部分接口也是可以的。例如，上面我们在createScene中直接用常规的方法new一个sprite后，将其addChild到SceneView对象中，也可实现上面的结果。只是在真正用PB开发项目时，这种用法不推荐，一来没充分发挥PB的作用，二来以后维护起来也不方便。

private function createScene():void
  {
   var scene:SceneView = new SceneView();
   PBE.initializeScene(scene);
   var sprite:Sprite = new Sprite();
   sprite.graphics.clear();
   sprite.graphics.beginFill(0x000000);
   sprite.graphics.drawRect(0, 0, 200, 200);
   sprite.graphics.endFill();
   scene.addChild(sprite);
  }