使用shell进行数据千分、万分 小数截取

当我们对位数比较长的数字进行展示的时候，我们通常想对其进行千分展示。作为中国人，或许更乐意使用万分法。然后针对小数，如果位数过多最好也能够自定义截取。

前言

使用shell实现数字的千分、万分和小数的截取

一、sed的两种非常规语法介绍

1. 匹配组

实操发现书写正则的时候必须对(){}进行转义，为便于理解，这里会给出转义前后的2个版本。

# 未转义版：sed 's/([a-z]*)([0-9]*)(.*)/\2/g' $(小写字母)(数字)(其他)
$ echo aaa111bbb222 | sed 's/\([a-z]*\)\([0-9]*\)\(.*\)/\2/g'
111
$ echo aaa111bbb222 | sed 's/\([a-z]*\)\([0-9]*\)\(.*\)/\1\3/g'
aaabbb222
# 此正则的含义为依次匹配连续字母、连续数字和任意字符，每个()作为一个匹配组，依次与后面的\1、\2、\3...对应
# 可单独取出匹配组如\1；取出多个匹配组\1\3或者\3\2；取出时可加入其他字符hello\1world\3。

2. 循环

# 将下列字符串变成abac
$ echo aaaaaaabaaac | sed 's/a*b/ab/g;s/a*c/ac/g'
abac
# 这里我们尝试使用循环的方式实现
$ echo aaaaaaabaaac | sed 's/aa/a/g'
aaaabaac
# 将表达式使用 :a; ;ta包裹，即表示循环执行中间的expr
# echo aaaaaaabaaac | sed ':a;s/aa/a/g;ta'
abac

二. 数值的千分、万分 …小数位处理

1. 整数处理

# 未转义版：sed 's/([0-9]{1,})([0-9]{3})/\1,\2/g' 
# 第1个()表示匹配开头1位以上的数字
# 第2个()表示匹配几个数字 3表示千分，4表示万分，以此类推 ...
$ echo 12345678901234567890 | sed ':a;s/\([0-9]\{1,\}\)\([0-9]\{3\}\)/\1,\2/g;ta'
12,345,678,901,234,567,890
$ echo 12345678901234567890 | sed ':a;s/\([0-9]\{1,\}\)\([0-9]\{4\}\)/\1,\2/g;ta'
1234,5678,9012,3456,7890
$ echo 12345678901234567890 | sed ':a;s/\([0-9]\{1,\}\)\([0-9]\{6\}\)/\1,\2/g;ta'
12,345678,901234,567890

2. 小数处理

# 未转义版：sed ':a;s/([0-9]{1,})([0-9]{4})(.[0-9]{3})*([0-9]*)/\1,\2\3/g;ta'
# 第1和2个()含义同上
# 第3个()表示匹配的小数位数 可自由指定
# 第4个()表示被截取小数的剩余部分
$ echo 1234567890.1234567890 |sed ':a;s/\([0-9]\{1,\}\)\([0-9]\{4\}\)\(\.[0-9]\{3\}\)*\([0-9]*\)/\1,\2\3/g;ta'
12,3456,7890.123# 如果小数保留的位数大于整数部分切分的位数，小数部分也会被格式化
$ echo 1234567890.1234567890 |sed ':a;s/\([0-9]\{1,\}\)\([0-9]\{3\}\)\(\.[0-9]\{5\}\)*\([0-9]*\)/\1,\2\3/g;ta'
1,234,567,890.12,345
# 解决方法：在第1个()前加^
$ echo 1234567890.1234567890 |sed ':a;s/\(^[0-9]\{1,\}\)\([0-9]\{3\}\)\(\.[0-9]\{5\}\)*\([0-9]*\)/\1,\2\3/g;ta'
1,234,567,890.12345# 如果遇到负数 在上述基础上^的后面增加-*即可
$ echo -1234567890.1234567890 |sed ':a;s/\(^-*[0-9]\{1,\}\)\([0-9]\{3\}\)\(\.[0-9]\{5\}\)*\([0-9]*\)/\1,\2\3/g;ta'
-1,234,567,890.12345

3. 使用perl处理 原文链接

$ echo '1234567890' | perl -pe 's/(?<=\d)(?=(\d{3})+\b)/,/g'
1,234,567,890
$ echo '1234567890.123456' | perl -pe 's/(?<=\d)(?=(\d{4})+\b)/,/g'
12,3456,7890.12,3456