Sq lServer try catch 捕获不到的一些错误及解决方法

本文主要是介绍Sq lServer try catch 捕获不到的一些错误及解决方法，希望对大家解决编程问题提供一定的参考价值，需要的开发者们随着小编来一起学习吧！

SqlServer try catch 捕获不到的一些错误及解决方法

IF (OBJECT_ID('AA','U') IS NOT NULL)
DROP TABLE AA
CREATE TABLE AA(ID INT)
SELECT * FROM AA
--注：数据库当前只存在表AA，无表#BB和表BB
-----------------------------------------------------
-----------------------------------------------------
-- 【案例1】
BEGIN TRAN
BEGIN TRY
INSERT INTO AA SELECT 1 --A处
INSERT INTO #BB SELECT 1 --B处
COMMIT TRAN;
END TRY
BEGIN CATCH
SELECT ERROR_MESSAGE() AS ErrorMessage
,ERROR_SEVERITY() AS ErrorSeverity
,ERROR_STATE() AS ErrorState
ROLLBACK TRAN;
END CATCH
/*运行结果:
(1 行受影响)
消息 208，级别 16，状态 0，第 4 行
对象名 '#BB' 无效。
说明:A处已经执行;B处中断操作,下面语句未执行
查询表AA已经有数据,此时可手动继续操作提交或回滚
*/
-----------------------------------------------------
-----------------------------------------------------
-- 【案例2】
BEGIN TRAN
BEGIN TRY
INSERT INTO AA SELECT 1 --A处
INSERT INTO BB SELECT 1 --B处
COMMIT TRAN;
END TRY
BEGIN CATCH
SELECT ERROR_MESSAGE() AS ErrorMessage
,ERROR_SEVERITY() AS ErrorSeverity
,ERROR_STATE() AS ErrorState
ROLLBACK TRAN;
END CATCH
/*运行结果:
注意：【案例1】使用临时表#BB，【案例2】使用表BB
选中代码执行两次，结果不一样！
第一次执行结果（不捕获异常），同【案例1】：
(1 行受影响)
消息 208，级别 16，状态 0，第 4 行
对象名 '#BB' 无效。
第二次执行结果（捕获异常）：
ErrorMessage ErrorSeverity ErrorState
对象名 'BB' 无效。 16 1
*/
-----------------------------------------------------
-----------------------------------------------------
-- 【案例3】
BEGIN TRAN
BEGIN TRY
INSERT INTO AA SELECT 1 --A处
INSERT INTO AA SELECT 'kk' --B处
COMMIT TRAN;
END TRY
BEGIN CATCH
SELECT ERROR_MESSAGE() AS ErrorMessage
,ERROR_SEVERITY() AS ErrorSeverity
,ERROR_STATE() AS ErrorState
ROLLBACK TRAN;
END CATCH
/*运行结果（正常捕获异常）：
ErrorMessage ErrorSeverity ErrorState
在将 varchar 值 'kk' 转换成数据类型 int 时失败。 16 1
*/
-----------------------------------------------------
-----------------------------------------------------
-- 【案例4：解决方案】
BEGIN TRAN
BEGIN TRY
INSERT INTO AA SELECT 1 --A处
EXEC('INSERT INTO #BB SELECT 1')--B处
COMMIT TRAN;
END TRY
BEGIN CATCH
SELECT ERROR_MESSAGE() AS ErrorMessage
,ERROR_SEVERITY() AS ErrorSeverity
,ERROR_STATE() AS ErrorState
ROLLBACK TRAN;
END CATCH
/*正常捕获异常！
不报之前错误：对象名 '#BB' 无效。
但要求格式为：EXEC(@sql)
*/
-----------------------------------------------------
-----------------------------------------------------
-- 【案例5：解决方案】
SET XACT_ABORT ON
BEGIN TRAN
BEGIN TRY
INSERT INTO AA SELECT 1 --A处
INSERT INTO #BB SELECT 1 --B处
COMMIT TRAN;
END TRY
BEGIN CATCH
SELECT ERROR_MESSAGE() AS ErrorMessage
,ERROR_SEVERITY() AS ErrorSeverity
,ERROR_STATE() AS ErrorState
ROLLBACK TRAN;
END CATCH
SET XACT_ABORT OFF
/*运行结果：
(1 行受影响)
消息 208，级别 16，状态 0，第 5 行
对象名 '#BB' 无效。
报错，但是事务会自动回滚.
系统默认： SET XACT_ABORT OFF
当 SET XACT_ABORT 为 ON 时，如果执行 Transact-SQL 语句产生运行时错误，则整个事务将终止并回滚。
*/
--查看 XACT_ABORT 是否打开
SELECT (CASE WHEN (16384 & @@OPTIONS) = 16384 THEN 'ON' ELSE 'OFF' END) AS XACT_ABORT;
/*
1. 轻微错误（严重性级别为0-10）：默认情况下不会给客户程序发送错误消息，继续工作。也就是说它无法被CATCH到
2. 中等错误（严重性级别为11-19）：能够被CATCH到（不管是在T-SQL里面还是在客户程序里面）
3. 严重错误（严重性级别为20-25）：SQL Server将强制把连接关掉。很显然这也不可能被CATCH到
【重点提示！！】
由于业务的复杂或者系统性能问题，致使数据库sql语句执行较久。
导致客户端网页已经连接超时（如设置为30秒）
此时数据库批处理语句未执行完成，客户session断开，相当于中断操作，类似【案例1】的中断。
事务是没有提交或回滚的，资源仍在占用，导致发生堵塞或死锁！~
【解决方法】：
在批处理语句前加上 SET XACT_ABORT ON
当客户端中断的时候，未执行完成则回滚操作，及时释放资源。
*/