QT程序安装包制作

本文主要是介绍QT程序安装包制作，希望对大家解决编程问题提供一定的参考价值，需要的开发者们随着小编来一起学习吧！

1.Inno Setup软件说明

Inno Setup 是一个免费的安装制作软件，小巧、简便、精美是其最大特点，支持pascal脚本，能快速制作出标准Windows2000风格的安装界面，足以完成一般安装任务。

2.使用说明

2.1.新建一个工程

2.2 填写要打包的软件的信息

如软件名称，版本等信息。

这个是用户是否可以更改应用程序文件夹名称选项。

注意：

如果我想在程序的安装目录下，生成一个doc目录，该目录下放一些程序的说明文档，比如readme文件。

许可和语言按需选择，不使用的话跳过即可。

************************************************************************************************

找到输出的文件路径

安装：（本次demo安装到G盘）

进到Ｇ盘查看，已经有该文件夹，且文件夹下有子文件夹doc。doc中有设置 readme.txt文件。

G盘根目录，生成IO_test文件夹。

doc文件夹，readme.txt文件

至此，一个简单的打包过程介绍结束。

******************************************************************************************

上述文档下载点击打开链接

******************************************************************************************

以下转的点击打开链接

[cpp]  view plain  copy
<pre name="code" class="plain">; 脚本由 Inno Setup 脚本向导 生成！  
; 有关创建 Inno Setup 脚本文件的详细资料请查阅帮助文档！  
;Inno Setup 是一个免费的 Windows 安装程序制作软件。  
;第一次发表是在 1997 年，Inno Setup 今天在功能设置和稳定性上的竞争力可能已经超过一些商业的安装程序制作软件  
;它是真正免费的软件，即使作为商业应用  
;还有一个特点，压缩率特别高，特别适合VB软件，我这个安装打包后只有3.7M，其他打包工具5M多  
;安装程序用编译脚本的方式创建，脚本其实就是一个类似 .INI 文件格式的 ASCII 码文本文件。 (它不象你想象的那么复杂!)  
;脚本文件一般可以用安装程序编译器程序内置的编辑器进行编辑。在你编写完脚本后，下一个最终步骤就是选择安装程序编译器  
;中的“编译”。创建完成后，就可以运行根据你脚本编译的安装程序了。  
;按默认，这个安装程序创建在包含脚本文件目录下的名为“输出”目录中  
  
  
  
[Setup]  
;这个段包含用于安装程序和卸载程序的全局设置。某些提示对于你创建的任何安装程序都是必需的  
;一个必需的指示，用以指定你正在安装的应用程序的标题。不包含版本号，与 AppVerName 指示用于同样的目的。AppName 始终在安装过程中显示在安装屏幕的左上角以及安装向导中  
AppName=南才北往  
;这个必需的指示值应该与 AppName 的值相同 (或类似)，但它还应该包含程序的版本号  
AppVerName=南才北往 V1.0  
;这是所有用于在 Windows 2000/XP 中添加/删除程序控件面板对话框中的“支持”信息中显示的内容。这些设置是可选的，在早期的 Windows 版本中无效  
AppPublisher=南才北往  
;这是所有用于在 Windows 2000/XP 中添加/删除程序控件面板对话框中的“支持”信息中显示的内容。这些设置是可选的，在早期的 Windows 版本中无效  
AppPublisherURL=http://www.upc.edu.cn  
AppSupportURL=http://www.upc.edu.cn  
AppUpdatesURL=http://www.upc.edu.cn  
;这个必需的指示值是用于选择目标位置向导面中的默认目录名，通常它用一个目录常量作为前缀，{pf}\SinyoCDManager将显示:C:\Program Files\SinyoCDManager  
DefaultDirName={pf}\南才北往  
;这个指示的值是用在向导的选择开始菜单文件夹页中使用的默认开始菜单文件夹名。如果这个指示是空白或未指定，它将用“默认”作为名字  
DefaultGroupName=南才北往  
  
InfoBeforeFile=D:\南才北往\使用说明.txt  
;指定许可协议文件名 (可选)，用 .txt 或 .rtf (富文本) 格式，在用户选择程序目标目录前显示  
LicenseFile=D:\南才北往\License.txt  
;指定“自述”文件名 (可选)，用 .txt 或 .rtf (富文本) 格式，用于在安装完成后显示  
;InfoAfterFile=D:\南才北往\使用说明.txt  
;这是指定要在文件中使用的压缩方法，以及压缩标准  
Compression=lzma  
;如果设为 yes，固实压缩将启用。这会使所有文件一次性压缩  
SolidCompression=yes  
  
VersionInfoCompany=HTTP://www.upc.edu.cn  
VersionInfoDescription=南才北往  
VersionInfoVersion=1.0.0.0  
VersionInfoCopyright=Copyright (C) 2009-2010 CDream  
;可重新修复软件  
;AppModifyPath="{app}\Setup.exe" /modify=1  
;资源管理器更改环境变量  
;ChangesEnvironment=1  
;[Tasks]  
;这个段是只选的。它定义安装程序在执行安装期间所有由用户定制的任务。这些任务以选项框和单选项形式在附加任务向导页中出现  
; 注意: 下面的条目包含一个中文用语 (“创建桌面快捷方式”和“添加快捷方式”)。如果需要你可以翻译为其它语言。  
[Tasks]  
Name: "desktopicon"; Description: "创建桌面快捷方式"; GroupDescription: "添加快捷方式:"; Flags: checkedonce  
; 注意: 下面的条目包含一个中文用语 (“创建快速运行栏快捷方式”和“添加快捷方式”)。如果需要你可以翻译为其它语言。  
;Name: "quicklaunchicon"; Description: "创建快速运行栏快捷方式"; GroupDescription: "添加快捷方式:"; Flags: checkedonce  
  
[Files]  
;这是定义安装程序安装文件到用户系统中的可选文件段  
;因这是VB软件，除软件本身包含的文件外，还必须包含相关的链接库  
;以下即软件本身的文件，注：安装目录下有一个 "\Config" 的子目录  
Source: "D:\南才北往\License.txt"; DestDir: "{app}"; Flags: ignoreversion  
Source: "D:\南才北往\使用说明.txt"; DestDir: "{app}"; Flags: ignoreversion  
Source: "D:\南才北往\帮助.chm"; DestDir: "{app}"; Flags: ignoreversion  
Source: "D:\南才北往\使用手册.doc"; DestDir: "{app}"; Flags: isreadme  
Source: "D:\南才北往\Config\*"; DestDir: "{app}\Config"; Flags: ignoreversion recursesubdirs createallsubdirs  
Source: "D:\南才北往\XdictGrb.dll"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace uninsneveruninstall sharedfile regserver  
Source: "D:\南才北往\msvcrt.dll"; DestDir: "{sys}"; CopyMode: alwaysskipifsameorolder; Flags: restartreplace uninsneveruninstall sharedfile  
; 注意: 不要在任何共享系统文件中使用“Flags: ignoreversion”  
[INI]  
;这是你希望安装程序在用户系统中设置 .INI 文件条目的可选段。  
;写一个文件“访问我们.url”用于访问作者网站  
Filename: "{app}\访问我们.url"; Section: "InternetShortcut"; Key: "URL"; String: "http://www.upc.edu.cn";  
  
[Icons]  
;这个可选段定义所有创建在开始菜单和/或其它位置 (比如桌面) 的快捷方式  
Name: "{group}\南才北往"; Filename: "{app}\Recognise.exe"; WorkingDir:"{app}"  
Name: "{group}\帮助"; Filename: "{app}\帮助.chm"; WorkingDir:"{app}"  
Name: "{group}\使用说明"; Filename: "{app}\使用说明.txt"; WorkingDir:"{app}"  
  
; 注意: 下列条目包含一个中文用语 (“网站”)。如果需要你可以翻译为其它语言。  
Name: "{group}\访问主页"; Filename: "{app}\访问我们.url"; WorkingDir:"{app}"  
Name: "{group}\卸载"; Filename: "{app}\unins000.exe"  
  
Name: "{userdesktop}\南才北往"; Filename: "{app}\Recognise.exe"; Tasks: desktopicon; WorkingDir:"{app}"  
;Name: "{userappdata}\Microsoft\Internet Explorer\Quick Launch\南才北往"; Filename: "{app}\Recognise.exe"; Tasks: quicklaunchicon; WorkingDir:"{app}"  
  
[Run]  
; 注意: 下列条目包含一个中文用语 (“运行”)。如果需要你可以翻译为其它语言。  
;[Run] 段是可选的，用来指定程序完成安装后、在安装程序显示最终对话框之前要执行的程序  
Filename: "{app}\Recognise.exe"; Description: "运行 南才北往"; Flags: nowait postinstall skipifsilent  
  
;更改显示在程序中显示的消息文本  
[Messages]  
BeveledLabel=南才北往  
;卸载对话框说明  
ConfirmUninstall=您真的想要从电脑中卸载南才北往吗?%n%n按 [是] 则完全删除 %1 以及它的所有组件;%n按 [否]则让软件继续留在您的电脑上.  
;定义解压说明  
;StatusExtractFiles=解压并复制主程序文件及相关库文件...  
  
;用与在用户系统中创建，修改或删除注册表健值  
  
[UninstallDelete]  
;这个可选段定义你想让卸载程序删除除用 [Files] 或 [Dirs] 条目安装/创建外的其它文件或目录，或由你应用程序创建的一些公共使用的 .INI 文件。卸载程序在卸载时最后一步处理这些条目  
Type: files; Name: "{app}\访问我们.url"  