VB获取所有进程+结束进程（COX控件）

1、添加一个 “添加用户控件”，命名为“StartupList”，代码如下：
Option Explicit
Private Declare Function CreateToolhelpSnapshot Lib “kernel32” Alias “CreateToolhelp32Snapshot” (ByVal lFlags As Long, ByVal lProcessID As Long) As Long
Private Declare Function ProcessFirst Lib “kernel32” Alias “Process32First” (ByVal hSnapShot As Long, uProcess As PROCESSENTRY32) As Long
Private Declare Function ProcessNext Lib “kernel32” Alias “Process32Next” (ByVal hSnapShot As Long, uProcess As PROCESSENTRY32) As Long
Private Declare Function TerminateProcess Lib “kernel32” (ByVal hProcess As Long, ByVal uExitCode As Long) As Long
Private Declare Function OpenProcess Lib “kernel32” (ByVal dwDesiredAccess As Long, ByVal bInheritHandle As Long, ByVal dwProcessId As Long) As Long
Private Declare Function CloseHandle Lib “kernel32” (ByVal hObject As Long) As Long
Const MAX_PATH As Integer = 260
Private Type PROCESSENTRY32
dwSize As Long
cntUsage As Long
th32ProcessID As Long
th32DefaultHeapID As Long
th32ModuleID As Long
cntThreads As Long
th32ParentProcessID As Long
pcPriClassBase As Long
dwFlags As Long
szExeFile As String * MAX_PATH
End Type
Const TH32CS_SNAPheaplist = &H1
Const TH32CS_SNAPPROCESS = &H2
Const TH32CS_SNAPthread = &H4
Const TH32CS_SNAPmodule = &H8
Const TH32CS_SNAPall = TH32CS_SNAPPROCESS + TH32CS_SNAPheaplist + TH32CS_SNAPthread + TH32CS_SNAPmodule
Dim WithEvents StartTheItem_ID As ListBox 'ID列表
Dim WithEvents Startup As ListBox '显示启动项列表

Private Sub Startup_Click()
StartTheItem_ID.ListIndex = Startup.ListIndex
End Sub

Private Sub UserControl_Initialize()
UserControl.AutoRedraw = True
Set StartTheItem_ID = UserControl.Controls.Add(“VB.ListBox”, “StartTheItem_ID”)
Set Startup = UserControl.Controls.Add(“VB.ListBox”, “Startup”)
StartTheItem_ID.Visible = False
Startup.Appearance = 0: Startup.Visible = True
Call Refresh
End Sub

Private Sub UserControl_Resize()
Startup.Move 0, 0, UserControl.ScaleWidth, UserControl.ScaleHeight
UserControl.Height = Startup.Height
End Sub

Public Sub Refresh() '刷新
Dim I As Long, lPid As Long, Proc As PROCESSENTRY32, hSnapShot As Long
StartTheItem_ID.Clear
Startup.Clear
hSnapShot = CreateToolhelpSnapshot(TH32CS_SNAPall, 0) '获得进程“快照”的句柄
Proc.dwSize = Len(Proc)
lPid = ProcessFirst(hSnapShot, Proc) '获取第一个进程的PROCESSENTRY32结构信息数据
I = 0
Do While lPid <> 0 '当返回值非零时继续获取下一个进程
StartTheItem_ID.AddItem Hex(Proc.th32ProcessID)
Startup.AddItem Proc.szExeFile
I = I + 1
lPid = ProcessNext(hSnapShot, Proc) '循环获取下一个进程的PROCESSENTRY32结构信息数据
Loop
CloseHandle hSnapShot '关闭进程“快照”句柄
End Sub

Public Function CloseProcess() As Boolean '关闭进程,成功返回 True,失败返回 False
Dim lPHand As Long, TMBack As Long
lPHand = Val("&H" & StartTheItem_ID.List(StartTheItem_ID.ListIndex))
lPHand = OpenProcess(1&, True, lPHand) '获取进程句柄
TMBack = TerminateProcess(lPHand, 0&) '关闭进程
CloseProcess = IIf(TMBack <> 0, True, False)
CloseHandle lPHand
If CloseProcess Then Call Refresh '刷新进程列表
End Function

Public Function TipOff() As Long '关闭进程时返回一个提示信息
If Startup.ListCount <> 0 Then
TipOff = IIf(Startup.Text <> “”, 1, 0)
Else
TipOff = -1
End If
End Function

Public Function List()
List = Startup.List(Startup.ListIndex)
End Function

2、在FORM里把StartupList添加到窗体和两个Command1、Command2，代码如下：
Option Explicit
Private Sub Command1_Click()
StartupList1.Refresh
End Sub

Private Sub Command2_Click()
Dim I As Long, D As Boolean
If StartupList1.TipOff > 0 Then
I = MsgBox(“真的要关闭：” & StartupList1.List & " 吗？", vbYesNo, “提示”)
If I = 6 Then
D = StartupList1.CloseProcess
MsgBox IIf(D, “关闭进程成功！”, “关闭进程失败！”), vbOKOnly, “提示”
End If
End If
End Sub

Private Sub Form_Load()
Command1.Caption = “刷新”
Command2.Caption = “结束进程”
End Sub